locals {
  app_slug = "${var.instance}${var.component==""?"":"-"}${var.component}"
  pres_labels = merge(var.labels, {
    "app.kubernetes.io/component" = "presentation"
  })
  rules = [for v in var.dns_names : {
    "host" = "${v}"
    "http" = {
      "paths" = [for idx, svc in var.services : {
        "path"     = "/${var.sub_paths[idx]}"
        "pathType" = "Prefix"
        "backend" = {
          "service" = svc
        }
      }]
    }
  }]
  tls = var.enforce_tls ? [
    {
      secretName = var.cert_name != "" ? var.cert_name : "${local.app_slug}-cert"
      hosts      = var.dns_names
    }
  ] : []
  middlewares = concat(
    var.create_redirect ? ["${local.app_slug}-https"] : [],
    var.middlewares
  )
  annotations = merge(
    var.entrypoint != "" ? {
      "traefik.ingress.kubernetes.io/router.entrypoints" = var.entrypoint
    } : {},
    length(local.middlewares) > 0 ? {
      "traefik.ingress.kubernetes.io/router.middlewares" : "${join(",", [for m in local.middlewares : format("%s-%s@kubernetescrd", var.namespace, m)])}"
    } : {},
  )
}

resource "kubectl_manifest" "prj_certificate" {
  count     = var.create_cert ? 1 : 0
  yaml_body = <<-EOF
    apiVersion: "cert-manager.io/v1"
    kind: "Certificate"
    metadata:
      name: "${local.app_slug}"
      namespace: "${var.namespace}"
      labels: ${jsonencode(local.pres_labels)}
    spec:
        secretName: "${local.app_slug}-cert"
        dnsNames: ${jsonencode(var.dns_names)}
        issuerRef:
          kind: "ClusterIssuer"
          name: "${var.issuer}"
          group: "cert-manager.io"
  EOF
}

resource "kubectl_manifest" "prj_https_redirect" {
  count     = var.create_redirect || var.component == "" ? 1 : 0
  yaml_body = <<-EOF
    apiVersion: "traefik.containo.us/v1alpha1"
    kind: "Middleware"
    metadata:
      name: "${local.app_slug}-https"
      namespace: "${var.namespace}"
      labels: ${jsonencode(local.pres_labels)}
    spec:
      redirectScheme:
        scheme: "https"
        permanent: true
  EOF
}

resource "kubectl_manifest" "prj_ingress" {
  force_conflicts = true
  yaml_body       = <<-EOF
    apiVersion: "networking.k8s.io/v1"
    kind: "Ingress"
    metadata:
      name: "${local.app_slug}"
      namespace: "${var.namespace}"
      labels: ${jsonencode(local.pres_labels)}
      annotations: ${jsonencode(local.annotations)}
    spec:
      ingressClassName: "${var.ingress_class}"
      rules: ${jsonencode(local.rules)}
      tls: ${jsonencode(local.tls)}
  EOF
}