locals {
    annotations = {
      "vynil.solidite.fr/meta" = var.component
      "vynil.solidite.fr/name" = "${var.domain}-devspaces"
      "vynil.solidite.fr/domain" = var.domain-name
      "vynil.solidite.fr/issuer" = var.issuer
      "vynil.solidite.fr/ingress" = var.ingress-class
    }
    global = {
        "domain"         = var.domain
        "domain-name"    = var.domain-name
        "issuer"         = var.issuer
        "ingress-class"  = var.ingress-class
        "backups"        = var.backups
        "app-group"      = var.app-group
    }
    global-apps = merge(local.global, {
      "domain-name"    = "devtools.${var.domain-name}"
      "app-group"      = "dev"
    })
    okd = merge({
      "namespaces" = concat([
          for station in local.sorted-station-names: "${var.domain}-devspaces-${station}"
        ],flatten([
          for org in local.sorted-organisations:[
            for stage in reverse(distinct(sort([for s in lookup(org, "stages", []): s.name]))): "${var.domain}-org-${org.name}-${stage}"
          ]
        ])
      )
    }, { for k, v in var.apps.okd : k => v if k!="enable" })
    gramo = merge({
      "namespaces" = concat([
          for station in local.sorted-station-names: "${var.domain}-devspaces-${station}"
        ],flatten([
          for org in local.sorted-organisations:[
            for stage in reverse(distinct(sort([for s in lookup(org, "stages", []): s.name]))): "${var.domain}-org-${org.name}-${stage}"
          ]
        ])
      )
    }, { for k, v in var.apps.gramo : k => v if k!="enable" })
    dbgate = merge({
      "pg" = concat(
        flatten([for ds in local.sorted-datasets: [for db in lookup(ds, "databases", []): {
          "name" = "${ds.name}-dataset-pg"
          "namespace" = ds.namespace
          "dbname" = db.name
          "username" = db.name
          "secret" = {
            "name" = "${ds.name}-dataset-pg-${db.name}"
            "key" = "POSGRESQL_PASSWORD"
          }
        }] if ds.engine=="pg"]),
        flatten([for ds in local.sorted-datasets: {
          "name" = "${ds.name}-dataset-pg"
          "namespace" = ds.namespace
          "dbname" = ds.name
          "username" = ds.name
          "secret" = {
            "name" = "${ds.name}-dataset-pg-app"
            "key" = "password"
          }
        } if ds.engine=="pg"]),
        flatten([for org in local.sorted-organisations: flatten([for stage in lookup(org, "stages", []): flatten([for ds in org.datasets: [for db in lookup(ds, "databases", []):{
          "name" = "${ds.name}-dataset-pg"
          "namespace" = "${var.domain}-org-${org.name}-${stage.name}"
          "dbname" = db.name
          "username" = db.name
          "secret" = {
            "name" = "${ds.name}-dataset-pg-${db.name}"
            "key" = "POSGRESQL_PASSWORD"
          }
        }] if ds.engine=="pg"])])]),
        flatten([for org in local.sorted-organisations: flatten([for stage in lookup(org, "stages", []): flatten([for ds in org.datasets: {
          "name" = "${ds.name}-dataset-pg"
          "namespace" = "${var.domain}-org-${org.name}-${stage.name}"
          "dbname" = ds.name
          "username" = ds.name
          "secret" = {
            "name" = "${ds.name}-dataset-pg-app"
            "key" = "password"
          }
        } if ds.engine=="pg"])])]),
        var.external-pgs
      )
      "maria" = concat(
        flatten([for ds in local.sorted-datasets: {
          "name" = "${ds.name}-dataset-maria"
          "namespace" = ds.namespace
          "dbname" = ds.name
          "username" = ds.name
          "secret" = {
            "name" = "${ds.name}-dataset-maria"
            "key" = "password"
          }
        } if ds.engine=="maria"]),
        flatten([for org in local.sorted-organisations: flatten([for stage in lookup(org, "stages", []): [for ds in org.datasets: {
          "name" = "${ds.name}-dataset-maria"
          "namespace" = "${var.domain}-org-${org.name}-${stage.name}"
          "dbname" = ds.name
          "username" = ds.name
          "secret" = {
            "name" = "${ds.name}-dataset-maria"
            "key" = "password"
          }
        } if ds.engine=="maria"]])]),
        var.external-marias
      )
      "mongo" = concat(
        flatten([for ds in local.sorted-datasets: {
          "name" = "${ds.name}-dataset-mongo"
          "namespace" = ds.namespace
          "dbname" = ds.name
          "username" = ds.name
          "secret" = {
            "name" = "${ds.name}-dataset-mongo"
            "key" = "password"
          }
        } if ds.engine=="mongo"]),
        flatten([for org in local.sorted-organisations: flatten([for stage in lookup(org, "stages", []): [for ds in org.datasets: {
          "name" = "${ds.name}-dataset-mongo"
          "namespace" = "${var.domain}-org-${org.name}-${stage.name}"
          "dbname" = ds.name
          "username" = ds.name
          "secret" = {
            "name" = "${ds.name}-dataset-mongo"
            "key" = "password"
          }
        } if ds.engine=="mongo"]])]),
        var.external-mongos
      )
      "redis" = concat(
        flatten([for ds in local.sorted-datasets: {
          "name" = "${ds.name}-dataset-redis"
          "namespace" = ds.namespace
        } if ds.engine=="mongo"]),
        flatten([for org in local.sorted-organisations: flatten([for stage in lookup(org, "stages", []): [for ds in org.datasets: {
          "name" = "${ds.name}-dataset-redis"
          "namespace" = "${var.domain}-org-${org.name}-${stage.name}"
        } if ds.engine=="mongo"]])]),
        var.external-redis
      )
    }, { for k, v in var.apps.dbgate : k => v if k!="enable" })
}

resource "kubernetes_namespace_v1" "apps-ns" {
  count = (var.apps.dbgate.enable || var.apps.okd.enable) ? 1 : 0
  metadata {
    annotations = local.annotations
    labels = merge(local.common-labels, local.annotations)
    name = "${var.namespace}-devapps"
  }
}

resource "kubectl_manifest" "okd" {
  count = var.apps.okd.enable ? 1 : 0
  depends_on = [kubernetes_namespace_v1.apps-ns]
  yaml_body  = <<-EOF
    apiVersion: "vynil.solidite.fr/v1"
    kind: "Install"
    metadata:
      name: "dev-okd"
      namespace: "${kubernetes_namespace_v1.apps-ns[0].metadata[0].name}"
      labels: ${jsonencode(local.common-labels)}
    spec:
      distrib: "${var.distributions.domain}"
      category: "apps"
      component: "okd"
      options: ${jsonencode(merge(local.global-apps, local.okd))}
  EOF
}

resource "kubectl_manifest" "gramo" {
  count = var.apps.gramo.enable ? 1 : 0
  depends_on = [kubernetes_namespace_v1.apps-ns]
  yaml_body  = <<-EOF
    apiVersion: "vynil.solidite.fr/v1"
    kind: "Install"
    metadata:
      name: "dev-gramo"
      namespace: "${kubernetes_namespace_v1.apps-ns[0].metadata[0].name}"
      labels: ${jsonencode(local.common-labels)}
    spec:
      distrib: "${var.distributions.domain}"
      category: "apps"
      component: "gramo"
      options: ${jsonencode(merge(local.global-apps, local.gramo))}
  EOF
}

resource "kubectl_manifest" "dbgate" {
  count = var.apps.dbgate.enable ? 1 : 0
  depends_on = [kubernetes_namespace_v1.apps-ns]
  yaml_body  = <<-EOF
    apiVersion: "vynil.solidite.fr/v1"
    kind: "Install"
    metadata:
      name: "dbgate"
      namespace: "${kubernetes_namespace_v1.apps-ns[0].metadata[0].name}"
      labels: ${jsonencode(local.common-labels)}
    spec:
      distrib: "${var.distributions.domain}"
      category: "apps"
      component: "dbgate"
      options: ${jsonencode(merge(local.global-apps, local.dbgate))}
  EOF
}