locals {
    rules = [ for v in var.dns_names : {
      "host" = "${v}"
      "http" = {
        "paths" = [{
          "backend"  = {
            "service" = var.service
          }
          "path"     = "/${var.sub-path}"
          "pathType" = "Prefix"
        }]
      }
    }]
}

resource "kubectl_manifest" "prj_certificate" {
  count = var.create_cert?1:0
  yaml_body  = <<-EOF
    apiVersion: "cert-manager.io/v1"
    kind: "Certificate"
    metadata:
      name: "${var.instance}${var.component==""?"":"-"}${var.component}"
      namespace: "${var.namespace}"
      labels: ${jsonencode(var.labels)}
    spec:
        secretName: "${var.instance}${var.component==""?"":"-"}${var.component}-cert"
        dnsNames: ${jsonencode(var.dns_names)}
        issuerRef:
          name: "${var.issuer}"
          kind: "ClusterIssuer"
          group: "cert-manager.io"
  EOF
}

resource "kubectl_manifest" "prj_https_redirect" {
  count = var.create_redirect||var.component==""?1:0
  yaml_body  = <<-EOF
    apiVersion: "traefik.io/v1alpha1"
    kind: "Middleware"
    metadata:
      name: "${var.instance}-https"
      namespace: "${var.namespace}"
      labels: ${jsonencode(var.labels)}
    spec:
      redirectScheme:
        scheme: "https"
        permanent: true
  EOF
}

resource "kubectl_manifest" "prj_ingress" {
  force_conflicts = true
  yaml_body  = <<-EOF
    apiVersion: "networking.k8s.io/v1"
    kind: "Ingress"
    metadata:
      name: "${var.instance}${var.component==""?"":"-${var.component}"}"
      namespace: "${var.namespace}"
      labels: ${jsonencode(var.labels)}
      annotations:
        "traefik.ingress.kubernetes.io/router.middlewares": "${join(",", [for m in concat(["${var.instance}-https"],var.middlewares) : format("%s-%s@kubernetescrd", var.namespace, m)])}"
    spec:
      ingressClassName: "${var.ingress_class}"
      rules: ${jsonencode(local.rules)}
      tls:
      - hosts: ${jsonencode(var.dns_names)}
        secretName: "${var.instance}${var.secret-component!=""?"-${var.secret-component}":var.component==""?"":"-${var.component}"}-cert"
  EOF
}