locals {
    annotations = {
      "vynil.solidite.fr/meta"   = var.component
      "vynil.solidite.fr/name"   = var.namespace
    }
    annotations_default = {
      "default.vynil.solidite.fr/domain_name" = var.domain_name
      "default.vynil.solidite.fr/timezone" = var.timezone
      "default.vynil.solidite.fr/language" = var.language
      "default.vynil.solidite.fr/domain" = var.domain
      "default.vynil.solidite.fr/issuer" = var.issuer
      "default.vynil.solidite.fr/ingress_class" = var.ingress_class
      "default.vynil.solidite.fr/app_group" = var.app_group
      "default.vynil.solidite.fr/backups.enable" = var.backups.enable
      "default.vynil.solidite.fr/backups.use_barman" = var.backups.use_barman
      "default.vynil.solidite.fr/backups.endpoint" = var.backups.endpoint
      "default.vynil.solidite.fr/backups.secret_name" = var.backups.secret_name
      "default.vynil.solidite.fr/backups.key_id_key" = var.backups.key_id_key
      "default.vynil.solidite.fr/backups.secret_key" = var.backups.secret_key
      "default.vynil.solidite.fr/backups.restic_key" = var.backups.restic_key
    }
    global = {
        "domain"        = var.namespace
        "domain_name"   = var.domain_name
        "issuer"        = var.issuer
        "ingress_class" = var.ingress_class
        "backups"       = var.backups
    }
    default-mode = var.storage-classes.FilesystemReadWriteMany!=""?"ReadWriteMany":"ReadWriteOnce"
    dolibarr = { for k, v in var.dolibarr : k => v if contains(["enable","storage"],k) }
    doli-storage = merge({
      "storage" = {
        "size" = lookup(lookup(local.dolibarr, "storage",{}), "size", "10Gi")
        "accessMode" = lookup(lookup(local.dolibarr, "storage",{}), "accessMode", local.default-mode)
        "type" = "Filesystem"
      }
    }, { for k, v in var.dolibarr : k => v if k=="storage" })
}

resource "kubernetes_namespace_v1" "erp-ns" {
  count = ( var.dolibarr.enable )? 1 : 0
  metadata {
    annotations = merge(local.annotations, local.annotations_default)
    labels = merge(local.common-labels, local.annotations)
    name = "${var.namespace}-erp"
  }
}

resource "kubectl_manifest" "dolibarr" {
  count = var.dolibarr.enable ? 1 : 0
  depends_on = [kubernetes_namespace_v1.erp-ns]
  yaml_body  = <<-EOF
    apiVersion: "vynil.solidite.fr/v1"
    kind: "Install"
    metadata:
      name: "dolibarr"
      namespace: "${kubernetes_namespace_v1.erp-ns[0].metadata[0].name}"
      labels: ${jsonencode(local.common-labels)}
    spec:
      distrib: "${var.distributions.domain}"
      category: "apps"
      component: "dolibarr"
      options: ${jsonencode(merge(local.global, local.doli-storage, local.dolibarr))}
  EOF
}