locals {
  pg-labels = merge(local.common-labels, {
    "app.kubernetes.io/component" = "pg"
  })
  pool-labels = merge(local.common-labels, {
    "app.kubernetes.io/component" = "pg-pool"
  })
}

resource "kubectl_manifest" "prj_pg" {
  yaml_body  = join("", concat([<<-EOF
    apiVersion: postgresql.cnpg.io/v1
    kind: Cluster
    metadata:
      name: "${var.instance}-${var.component}-pg"
      namespace: "${var.namespace}"
      labels: ${jsonencode(local.pg-labels)}
      annotations:
        "k8up.io/backupcommand": "pg_dump -U postgres -d ${var.component} --clean"
        "k8up.io/file-extension": ".sql"
    spec:
      instances: ${var.postgres.replicas}
      imageName: "${var.images.postgres.registry}/${var.images.postgres.repository}:${var.images.postgres.tag}"
      storage:
        size: "${var.storage.postgres}"
      bootstrap:
        initdb:
          database: "${var.component}"
          owner: "${var.component}"
      monitoring:
        enablePodMonitor: true
  EOF
  ], var.backups.enable&&var.backups.use-barman?[<<-EOF
      backup:
        barmanObjectStore:
          destinationPath: "s3://${var.instance}-${var.namespace}/"
          endpointURL: "${var.backups.endpoint}/barman"
          s3Credentials:
            accessKeyId:
              name: "${var.backups.secret-name}"
              key: "${var.backups.key-id-key}"
            secretAccessKey:
              name: "${var.backups.secret-name}"
              key: "${var.backups.secret-key}"
  EOF
  ]:[""]))
}

resource "kubectl_manifest" "prj_pg_backup" {
  count = var.backups.enable ? 1:0
  yaml_body  = <<-EOF
    apiVersion: postgresql.cnpg.io/v1
    kind: ScheduledBackup
    metadata:
      name: "${var.instance}-${var.component}-pg"
      namespace: "${var.namespace}"
      labels: ${jsonencode(local.pg-labels)}
    spec:
      schedule: "${var.backups.schedule.db}"
      backupOwnerReference: self
      cluster:
        name: "${var.instance}-${var.component}-pg"
  EOF
}

resource "kubectl_manifest" "prj_pg_pool" {
  depends_on = [kubectl_manifest.prj_pg]
  yaml_body  = <<-EOF
    apiVersion: postgresql.cnpg.io/v1
    kind: Pooler
    metadata:
      name: "${var.instance}-${var.component}-pool"
      namespace: "${var.namespace}"
      labels: ${jsonencode(local.pool-labels)}
    spec:
      cluster:
        name: "${var.instance}-${var.component}-pg"
      instances: 1
      type: rw
      pgbouncer:
        poolMode: session
        parameters:
          max_client_conn: "1000"
          default_pool_size: "10"
  EOF
}