
locals {
  common-labels = {
    "vynil.solidite.fr/owner-name" = var.instance
    "vynil.solidite.fr/owner-namespace" = var.namespace
    "vynil.solidite.fr/owner-category" = var.category
    "vynil.solidite.fr/owner-component" = var.component
    "app.kubernetes.io/managed-by" = "vynil"
    "app.kubernetes.io/name" = var.component
    "app.kubernetes.io/instance" = var.instance
  }
  rb-patch = <<-EOF
    - op: replace
      path: /subjects/0/namespace
      value: "${var.namespace}"
    EOF

}
data "kustomization_overlay" "data" {
  common_labels = local.common-labels
  namespace = var.namespace
  resources = [for file in fileset(path.module, "*.yaml"): file if file != "index.yaml" && length(regexall("ClusterRole",file))<1]
  patches {
    target {
      kind = "Deployment"
      name = "catalog-operator"
    }
    patch = <<-EOF
    - op: replace
      path: /spec/template/spec/containers/0/imagePullPolicy
      value: "${var.images.operator.pull_policy}"
    - op: replace
      path: /spec/template/spec/containers/0/image
      value: "${var.images.operator.registry}/${var.images.operator.repository}:${var.images.operator.tag}"
    - op: replace
      path: /spec/template/spec/containers/0/args/1
      value: "${var.namespace}"
    - op: replace
      path: /spec/template/spec/containers/0/args/4
      value: "${var.images.operator.registry}/${var.images.operator.repository}:${var.images.operator.tag}"
    EOF
  }
  patches {
    target {
      kind = "Deployment"
      name = "olm-operator"
    }
    patch = <<-EOF
    - op: replace
      path: /spec/template/spec/containers/0/imagePullPolicy
      value: "${var.images.operator.pull_policy}"
    - op: replace
      path: /spec/template/spec/containers/0/image
      value: "${var.images.operator.registry}/${var.images.operator.repository}:${var.images.operator.tag}"
    EOF
  }
}

data "kustomization_overlay" "data_no_ns" {
  common_labels = local.common-labels
  resources = [for file in fileset(path.module, "*.yaml"): file if file != "index.yaml" && (length(regexall("ClusterRole",file))>0)]
  patches {
    target {
      kind = "ClusterRoleBinding"
      name = "keda-hpa-controller-external-metrics"
    }
    patch = local.rb-patch
  }
}


